Perl. Библиотека программиста

Чтение строки из двоичного файла

Проблема

Требуется прочитать из файла строку, завершенную нуль-символом, начиная с определенного адреса.

Решение

Присвойте $/ нуль-символ ASCII и прочитайте строку с помощью <>:

$old_rs = $/;             # Сохранить старое значение $/
$/ = "\0";                # Нуль-символ
seek(FH, $addr, SEEK_SET) or die "Seek error: $!\n";
$string = <FH>;           # Прочитать строку
chomp $string;            # Удалить нуль-символ
$/ = $old_rs;             # Восстановить старое значение $/

При желании сохранение и восстановление $/ можно реализовать с помощью local:

{
  local $/ = "\0";
  # ...          # $/ восстанавливается автоматически
}

Комментарий

Следующая программа получает в качестве аргументов имя файла и одно или несколько байтовых смещений. Допускается десятичная, восьмеричная или шестнадцатеричная запись смещений. Для каждого смещения программа читает и выводит строку, которая начинается в данной позиции и завершается нуль-символом или концом файла:

#!/usr/bin/perl
# bgets - вывод строк по смещениям
use IO::Seekable;
($file, @addrs) = @ARGV or die "usage: $0 addr ...";
open(FH, $file)         or die "cannot open $file: $!";
$/ = "\000";
foreach $addr (@addrs) {
  $addr = oct $addr if $addr =~ /^0/;
  seek(FH, $addr, SEEK_SET)
  or die "can't seek to $addr in $file:  $!";
  printf qq{%#x %#o %d "%s"\n}, $addr, $addr, $addr, scalar <>;
}

Приведем простейшую реализацию программы UNIX strings

#!/usr/bin/perl
# strings - извлечение строк из двоичного файла
$/ = "\0";
while (<>) {
  while (/([\040-\176\s]{4,})/g) {
    print $1, "\n";
  }
}

См. также

Описание функций seek, getc и ord