Perl. Библиотека программиста

Создание устойчивых закрытых переменных

Проблема

Вы хотите, чтобы переменная сохраняла значение между вызовами подпрограммы, но не была доступна за ее пределами. Например, функция может запоминать, сколько раз она была вызвана.

Решение

«Заверните» функцию во внешний блок и объявите переменные my в области действия этого блока, а не в самой функции

{
  my $variable;
  sub mysub {
    # ...  обращение к $variable;
  }
}

Если переменные требуют инициализации, снабдите блок ключевым словом BEGIN, чтобы значение переменных заведомо задавалось перед началом работы основной программы:

BEGIN {
  my $variable = 1;    # начальное значение
  sub othersub {
    # ... обращение к $variable
  }
}

Комментарий

В отличие от локальных переменных в языках С и C++, лексические переменные Perl не всегда уничтожаются при выходе из области действия. Если нечто, продолжающее существовать, все еще помнит о лексической переменной, память не освобождается. В нашем примере mysub использует переменную $variable, поэтому Perl не освобождает память переменной при завершении блока, вмещающего определение mysub.

Счетчик вызовов реализуется следующим образом:

{
  my $counter;
  sub next_counter { return ++$counter }
}

При каждом вызове next_counter функция увеличивает и возвращает переменную $counter. При первом вызове переменная $counter имеет неопределенное значение, поэтому для оператора ++ она интерпретируется как 0. Переменная входит не в область действия next_counter, а в окружающий ее блок. Никакой внешний код не сможет изменить $counter без вызова next_counter.

Для расширения области действия обычно следует использовать ключевое слово BEGIN. В противном случае возможен вызов функции до инициализации переменной.

BEGIN {
  my $counter = 42;
  sub next_counter { return ++$counter }
  sub prev_counter { return --$counter }
}

Таким образом, в Perl создается аналог статических переменных языка С. В действительности он даже лучше — переменная не ограничивается одной функцией, и обе функции могут совместно использовать свою закрытую переменную.

Создание устойчивых закрытых переменных

Проблема

Решение

Комментарий

См. также