Perl. Библиотека программиста

Посимвольная обработка строк

Проблема

Требуется последовательно обрабатывать строку по одному символу.

Решение

Воспользуйтесь функцией split с пустым шаблоном, чтобы разбить строку на отдельные символы, или функцией unpack, если вам нужны лишь их ASCII-коды:

@array = split(//, $string);
@array = unpack("C*", $string);

Или последовательно выделяйте очередной символ в цикле:

while (/(.)/g)  { #  здесь не интерпретируется как новая строка
# Сделать что-то полезное с $1
}

Комментарий

Как говорилось выше, фундаментальной единицей текста в Perl является строка, а не символ. Необходимость посимвольной обработки строк возникает достаточно редко. Обычно такие задачи легче решаются с помощью высокоуровневых операций Perl (например, поиска по шаблону).

Если вызвать split с шаблоном, который совпадает с пустой строкой, функция возвращает список отдельных символов строки. При намеренном использовании эта особенность оказывается удобной, однако с ней можно столкнуться и случайно. Например, /X*/ совпадает с пустой строкой. Не исключено, что вам встретятся и другие ненамеренные совпадения.

Ниже приведен пример, который выводит символы строки "an apple a day", отсортированные в восходящем порядке ASCII-кодов:

%seen = ();
$string = "an apple a day";
foreach $byte (split //, $string) {
  $seen{$1}++;
}
print "unique chars are: ", sort(keys %seen), "\n";
unique chars are: adelnpy

Решения с функциями split и unpack предоставляют массив символов, с которым можно работать. Если массив не нужен, воспользуйтесь поиском по шаблону в цикле while с флагом /g, который будет извлекать по одному символу:

%seen = ():
$string = "an apple a day";
while ($string =~ /(.)/g) {
  $seen{$1}++;
}
print "unique chars are: ", sort(keys %seen), "\n";
unique chars are: adelnpy

Как правило, посимвольная обработка строк не является оптимальным решением. Вместо использования index/substr или split/unpack проще воспользоваться шаблоном. В следующем примере 32-разрядная контрольная сумма вычисляется вручную, но лучше поручить работу функции unpack — она сделает то же самое намного эффективнее.

Следующий пример вычисляет контрольную сумму символов $string в цикле fоreach. Приведенный алгоритм не оптимален; просто мы используем традиционную и относительно легко вычисляемую сумму. За более достойной реализацией контрольной суммы обращайтесь к модулю MD5 на CPAN.

$sum = 0;
foreach $ascval (unpack("C*", $string)) {
  $sum += $ascval;
}  
print "sum is $sum\n";
# Для строки "an apple a day" выводится сумма 1248

Следующий вариант делает то же самое, но намного быстрее:

$sum = unpack("%32C", $string);

Это позволяет эмулировать программу вычисления контрольной суммы SysV:

#!/usr/bin/perl
# sum - Вычисление 16-разрядной контрольной суммы всех входных файлов
$checksum = 0;
while (<>) { $checksum += unpack("%16C*", $_) }
Schecksum %= (2 ** 16) - 1;
print "$checksum\n";

В примере одна крошечная программа, в которой также реализована посимвольная обработка входных данных. Идея заключается в том, чтобы вывод каждого символа сопровождался небольшой паузой — текст будет появляться перед аудиторией в замедленном темпе, и его будет удобнее читать.

#!/usr/bin/perl
# slowcat – з а м е д л е н н ы й вывод
# использование: slowcat [-DELAY] [files...],
# где DELAY - задержка
$DELAY = ($ARGV[0] =~ /^-([.\d]+)/) ? (shift, $1) : 1;
$| = 1;
while (<>) {
  for (split(//))  {
    print;
    select(undef, undef, undef, 0.005 * $DELAY);
  }
}

См. также

Описание функций split, unpack и select